描述

如果事件日志文件的大小大于 20 MB，就将其备份和清除。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
   & "{ impersonationLevel=impersonate, (Backup, Security) }!\\" _
       & strComputer & "\root\cimv2")
Set colLogFiles = objWMIService.ExecQuery _
   ("Select * from Win32_NTEventLogFile")
For each objLogfile in colLogFiles
   If objLogFile.FileSize > 100000 Then
      strBackupLog = objLogFile.BackupEventLog _
          ("c:\scripts\" & objLogFile.LogFileName & ".evt")
      objLogFile.ClearEventLog()
   End If
Next

描述

备份和清除应用程序事件日志。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
   & "{ impersonationLevel=impersonate,(Backup) }!\\" & _
       strComputer & "\root\cimv2")
Set colLogFiles = objWMIService.ExecQuery _
   ("Select * from Win32_NTEventLogFile where LogFileName='Application'")
For Each objLogfile in colLogFiles
   errBackupLog = objLogFile.BackupEventLog("c:\scripts\application.evt")
   If errBackupLog <> 0 Then        
       Wscript.Echo "The Application event log could not be backed up."
   Else
       objLogFile.ClearEventLog()
   End If
Next

描述

将计算机的 IP 地址设置为 192.168.1.141，并将 IP 网关设置为 192.168.1.100。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetAdapters = objWMIService.ExecQuery _
   ("Select * from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
strIPAddress = Array("192.168.1.141")
strSubnetMask = Array("255.255.255.0")
strGateway = Array("192.168.1.100")
strGatewayMetric = Array(1)
For Each objNetAdapter in colNetAdapters
   errEnable = objNetAdapter.EnableStatic(strIPAddress, strSubnetMask)
   errGateways = objNetAdapter.SetGateways(strGateway, strGatewaymetric)
   If errEnable = 0 Then
       WScript.Echo "The IP address has been changed."
   Else
       WScript.Echo "The IP address could not be changed."
   End If
Next

描述

在 DNS 服务器上创建邮件交换器 (MX) DNS 记录。

有关在这段代码中使用的 CreateInstanceFromPropertyData 方法的更多信息，请单击此处。

支持平台

脚本代码
strDNSServer = "atl-dc-03.fabrikam.com"
strContainer = "fabrikam.com"
strOwner = "atl-srv-01.fabrikam.com"
intRecordClass = 1
intTTL = 600
intPreference = 0
strMailExchanger = "mailexchanger.fabrikam.com"
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\MicrosoftDNS")
Set objItem = objWMIService.Get("MicrosoftDNS_MXType")
errResult = objItem.CreateInstanceFromPropertyData _
   (strDNSServer, strContainer, strOwner, intRecordClass, intTTL, intPreference, strMailExchanger)

描述

在 DNS 服务器上创建名为 accounting.fabrikam.com 的主要 DNS 区域。

有关在这段代码中使用的 CreateZone 方法的更多信息，请单击此处。

支持平台

脚本代码
strZoneName = "accounting.fabrikam.com"
intPrimaryZone = 1
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\MicrosoftDNS")
Set objItem = objWMIService.Get("MicrosoftDNS_Zone")
errResult = objItem.CreateZone(strZoneName, intPrimaryZone)

描述

启用网络适配器的 IP 安全性。在此脚本中，所有的l TCP 和 UDP 端口以及所有的l IP 协议都是允许的；因此在每种情况下都传送值 0。如果只允许特定的端口或协议，则应该以数组的形式发送这些值。

有关在这段代码中使用的 EnableIPSec 方法的更多信息，请单击 此处。

支持平台

脚本代码
On Error Resume Next
Const ALLOW_ALL = 0
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetCards = objWMIService.ExecQuery _
   ("Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = True")
For Each objNetCard in colNetCards
   arrPermittedTCPPorts = Array(ALLOW_ALL)
   arrPermittedUDPPorts = Array(ALLOW_ALL)
   arrPermittedIPProtocols = Array(ALLOW_ALL)
   objNetCard.EnableIPSec arrPermittedTCPPorts, arrPermittedUDPPorts, arrPermittedIPProtocols
Next

string IPSecPermitTCPPorts[],  

string IPSecPermitUDPPorts[],  

string IPSecPermitIPProtocols[]

);

描述

返回安装在计算机中的每个支持 IP 的网络适配器的 IP 地址。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
   ("Select IPAddress from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
For Each IPConfig in IPConfigSet
   If Not IsNull(IPConfig.IPAddress) Then
       For i=LBound(IPConfig.IPAddress) to UBound(IPConfig.IPAddress)
           WScript.Echo IPConfig.IPAddress(i)
   Next
   End If
Next

描述
禁用所有配置为手动启动的服务。除了别的之外，这会使得 Power User 不能启动这些服务。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{ impersonationLevel=impersonate }!\\" & strComputer & "\root\cimv2")
Set colServiceList = objWMIService.ExecQuery _
("Select * from Win32_Service where StartMode = 'Manual'")
For Each objService in colServiceList
errReturnCode = objService.Change( , , , , "Disabled")  
Next

描述
返回在 Services.exe 进程中运行的服务的列表。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{ impersonationLevel=impersonate }!\\" & strComputer & "\root\cimv2")
Set colListOfServices = objWMIService.ExecQuery _
("Select * from Win32_Service")
For Each objService in colListOfServices
If objService.PathName = "C:\WINDOWS\system32\services.exe" Then
Wscript.Echo objService.DisplayName
End If
Next

描述
返回进程列表以及当前在每个进程中运行的所有服务。

脚本代码
set objIdDictionary = CreateObject("Scripting.Dictionary")
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{ impersonationLevel=impersonate }!\\" & strComputer & "\root\cimv2")
Set colServices = objWMIService.ExecQuery _
("Select * from Win32_Service Where State <> 'Stopped'")
For Each objService in colServices
If objIdDictionary.Exists(objService.ProcessID) Then
Else
objIdDictionary.Add objService.ProcessID, objService.ProcessID
End If
Next
colProcessIDs = objIdDictionary.Items
For i = 0 to objIdDictionary.Count - 1
Set colServices = objWMIService.ExecQuery _
("Select * from Win32_Service Where ProcessID = '" & _
colProcessIDs(i) & "'")
Wscript.Echo "Process ID: " & colProcessIDs(i)
For Each objService in colServices
Wscript.Echo VbTab & objService.DisplayName
Next
Next

描述
返回可以停止的服务的列表。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{ impersonationLevel=impersonate }!\\" & strComputer & "\root\cimv2")
Set colServices = objWMIService.ExecQuery _
("Select * from Win32_Service Where AcceptStop = True")
For Each objService in colServices
Wscript.Echo objService.DisplayName
Next

描述
返回可以暂停的服务的列表。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{ impersonationLevel=impersonate }!\\" & strComputer & "\root\cimv2")
Set colServices = objWMIService.ExecQuery _
("Select * from Win32_Service Where AcceptPause = True")
For Each objService in colServices
Wscript.Echo objService.DisplayName
Next

描述
删除名为 DbService 的假定服务。

脚本代码
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{ impersonationLevel=impersonate }!\\" & strComputer & "\root\cimv2")
Set colListOfServices = objWMIService.ExecQuery _
("Select * from Win32_Service Where Name = 'DbService'")
For Each objService in colListOfServices
objService.StopService()
objService.Delete()
Next

描述

演示脚本创建一个名为 Group1 的安全组，并且将一千个用户（UserNo1 到 UserNo10000）添加到该组。此脚本不可用于生产环境。

有关使用 ADSI 创建对象的更多信息，请单击 此处。

支持平台

脚本代码
Const ADS_PROPERTY_APPEND = 3
Set objRootDSE = GetObject("LDAP://rootDSE")
Set objContainer = GetObject("LDAP://cn=Users," & _
                              objRootDSE.Get("defaultNamingContext"))
Set objGroup = objContainer.Create("Group", "cn=Group1")
objGroup.Put "sAMAccountName","Group1"
objGroup.SetInfo
For i = 1 To 1000
strDN = ",cn=Users," & objRootDSE.defaultNamingContext
 objGroup.PutEx ADS_PROPERTY_APPEND, "member", _
   Array("cn=UserNo" & i & strDN)
 objGroup.SetInfo
Next
WScript.Echo "Group1 created and 1000 Users added to the group."

描述

绑定到计算机 MyComputer 上的本地管理员帐户，并且将该帐户的密码更改为 testpassword。

有关使用本地用户帐户的详细信息，请单击 此处。

支持平台

脚本代码
strComputer = "MyComputer"
Set objUser = GetObject("WinNT://" & strComputer & "/Administrator, user")
objUser.SetPassword "testpassword"
objUser.SetInfo

描述
演示脚本在 Active Directory 内的用户容器中创建 1,000 个用户帐户（名为 UserNo1、UserNo2、UserNo3 等等）。此脚本用于测试需要多个用户帐户的方案。

脚本代码
Set objRootDSE = GetObject("LDAP://rootDSE")
Set objContainer = GetObject("LDAP://cn=Users," & _
objRootDSE.Get("defaultNamingContext"))
For i = 1 To 1000
Set objLeaf = objContainer.Create("User", "cn=UserNo" & i)
objLeaf.Put "sAMAccountName", "UserNo" & i
objLeaf.SetInfo
Next
WScript.Echo "1000 Users created."

脚本代码
Set objUser = GetObject _
("LDAP://cn=MyerKen,ou=management,dc=fabrikam,dc=com")
objUser.SetPassword "i5A2sj*!"

描述

绑定到名为 atl-win2k-01 的计算机上的本地用户帐户，并且将帐号配置为在 2003 年 3 月 1 日过期。

有关使用本地用户帐户的详细信息，请单击此处。

支持平台

脚本代码

strComputer = "atl-win2k-01"
Set objUser = GetObject("WinNT:// " & strComputer & "/kenmyer ")
objUser.AccountExpirationDate = #03/01/2003#
objUser.SetInfo

有关使用 Windows Script Host 写入注册表的信息，请单击 此处。

支持平台

脚本代码

Set objShell = CreateObject("WScript.Shell")
objShell.RegWrite "HKCR\Folder\Shell\MenuText\Command\", "cmd.exe /k cd " & chr(34) & "%1" & chr(34)
objShell.RegWrite "HKCR\Folder\Shell\MenuText\", "Command Prompt Here"

说明

将本地计算机加入到域中，然后在 Active Directory 中创建该计算机的帐户。

支持的平台

脚本代码

Const JOIN_DOMAIN = 1
Const ACCT_CREATE = 2
Const ACCT_DELETE = 4
Const WIN9X_UPGRADE = 16
Const DOMAIN_JOIN_IF_JOINED = 32
Const JOIN_UNSECURE = 64
Const MACHINE_PASSWORD_PASSED = 128
Const DEFERRED_SPN_SET = 256
Const INSTALL_INVOCATION = 262144

strDomain = "FABRIKAM"
strPassword = "ls4k5ywA"
strUser = "shenalan"

Set objNetwork = CreateObject("WScript.Network")
strComputer = objNetwork.ComputerName

Set objComputer = GetObject("winmgmts:{ impersonationLevel=Impersonate }!\\" & _
strComputer & "\root\cimv2:Win32_ComputerSystem.Name='" & _
strComputer & "'")

ReturnValue = objComputer.JoinDomainOrWorkGroup(strDomain, _
strPassword, strDomain & "\" & strUser, NULL, _
JOIN_DOMAIN + ACCT_CREATE)